Xtykutl

I'm trying to create nested groups in a visual basic LINQ query expression as shown here in C#: https://docs.microsoft.com/en-us/dotnet/csharp/linq/create-a-nested-group:

    var queryNestedGroups =

    from student in students

    group student by student.Year into newGroup1

    from newGroup2 in

        (from student in newGroup1

         group student by student.LastName)

    group newGroup2 by newGroup1.Key;

This is what I have so far:

    Dim students As New List(Of Student)

    '...getting students content ommitted here...

    Dim queryNestedGroups As IEnumerable(Of IGrouping(Of Integer, IGrouping(Of String, Student))) =

            From student In students

            Group student By student.Year Into newGroup1 = Group

            From newGroup2 In (From student In newGroup1 Group student By student.LastName Into Group)

            Group newGroup2 By newGroup1.Key Into Group

'                              ^^^^^^^^^^^^^ compiler red lines here



    Dim grouping As IGrouping(Of Integer, IGrouping(Of String, Student))

    For Each grouping In queryNestedGroups

        Console.WriteLine($"DataClass.Student Level = {grouping.Key}")

        Dim grouping2 As IGrouping(Of String, Student)

        For Each grouping2 In grouping

            Console.WriteLine((ChrW(9) & "Names that begin with: " & grouping2.Key))

            Dim student As Student

            For Each student In grouping2

                Console.WriteLine((ChrW(9) & ChrW(9) & student.LastName & " " & student.FirstName))

            Next

        Next

    Next

But the compiler is complaining about the newGroup1.Key:

"Key" is not a member of "IEnumerable(Of Student)"

What is the Visual Basic equivalent of the C# code?

Thanks to Jimi, this produces the same result as the C# code:

    Dim queryNestedGroups =

            From student In students

            Group student By student.Year Into newGroup1 = Group

            From newGroup2 In (From student In newGroup1 Group student By LastName = student.LastName Into Group)

            Group newGroup2 By Year Into Group



    For Each grouping In queryNestedGroups

        Console.WriteLine($"DataClass.Student Level = {grouping.Year}")

        For Each grouping2 In grouping.Group

            Console.WriteLine((ChrW(9) & "Names that begin with: " & grouping2.LastName))

            Dim student As Student

            For Each student In grouping2.Group

                Console.WriteLine((ChrW(9) & ChrW(9) & student.LastName & " " & student.FirstName))

            Next

        Next

    Next

As a drawback the result queryNestedGroups is now an anonymous type and no

IEnumerable(Of IGrouping(Of Integer, IGrouping(Of String, Student)))

but at least it works!